//==========================================
// The wet bird atmospheric and camera settings
// Demonstration file
// Gilles Tran - May 2000
// -----------------------------------------
#include "colors.inc"
global_settings{
        assumed_gamma 1.0
}
#declare PdV=<50.01, 1.75, -10>;
camera
{
  location  PdV
  direction 6*z
  right     0.75*x
  look_at   <39.5, 12.0,  200.0>
}

background{White}

// -----------------------------------------
// Lights
// -----------------------------------------
#declare colLum=rgb<187,245,219>/255;

light_source{0  color colLum*0.3 translate <100,200,3000> fade_power 2 fade_distance 4000}
light_source{0  color colLum*0.3 translate <100,200,2000> fade_power 2 fade_distance 3000}
light_source{0  color colLum*1 translate <100,400,1000> fade_power 2 fade_distance 2000
area_light x*100,y*100 4,4 jitter // orient
}

light_source{<100,100,100> color colLum spotlight point_at <47,8,70> radius 20 falloff 30 tightness 1
area_light x*200,y*200 4,4 jitter // orient
}

light_source{0  color colLum*0.1 translate <100,600,-1000> fade_power 2 fade_distance 2000
area_light x*100,y*100 4,4 jitter // orient
}

// -----------------------------------------
// Sky layer
// -----------------------------------------
#declare Sky=plane{y,340 no_shadow hollow 
        texture{
                pigment{
                bozo turbulence 0.5  triangle_wave 
                color_map{[0 colLum*0.1][1 colLum*1.8]}
                }
                finish{ambient 1 diffuse 0.6}
                scale 700*<1,1,4>      
                translate <400,0,-1800>
                
        }
}




// -----------------------------------------
// Fogs
// -----------------------------------------
#declare sc=0.8/255;
#declare MainFog=fog{fog_type 1 color rgbf<187*sc,245*sc,219*sc,0.1> distance 5000}

#declare MiddleFog=union{triangle {0,x,x+y} triangle{0,y,x+y}
texture{
        pigment{
                planar
                pigment_map{
                        [0 gradient y poly_wave 0.5 color_map{[0 colLum*0.01][1 Clear]}]
                        [0.6 gradient y poly_wave  0.5 turbulence 0.1 lambda 3 color_map{[0 colLum*0.01][1 Clear]}]
                        [1 gradient y poly_wave 0.5  color_map{[0 colLum*0.01][1 Clear]}]
                }       
        }
        finish{ambient 0 diffuse 0.3}
        }
hollow
scale <100,30,1>
} 

#declare EndFog=box{<-200,0,0>,<100,350,0.001>
        texture{
                pigment{gradient y poly_wave 0.2 color_map{[0 Black][1 Clear]} scale 350}
                finish{ambient 0 diffuse 0.3}
        }
        translate -y*1
        no_shadow
        hollow
} 

// -----------------------------------------
// Atmosphere
// -----------------------------------------
object{Sky}      
fog{MainFog}
object{MiddleFog translate <-20,-1,1300>}
object{EndFog translate z*2400}


// -----------------------------------------
// Dummy buildings, ground and planes
// -----------------------------------------
#declare zStart=55;
#declare lB=465+zStart;
#declare xPosLeft=20;
#declare xPosBR_1=51;   
#declare c1=color rgb<0.90,0.96,0.88>;
#declare txtBL_1=texture{pigment{c1} finish{ambient 0 diffuse 0.6}}

box{<-30,0,-150>,<0,50,0> texture{pigment{colLum} finish{ambient 0 diffuse 0.3}} translate <10,0,390+zStart>}
box{<-31,0,0>,<0,73+5,62> texture{pigment{colLum}  finish{ambient 0 diffuse 0.3}} translate <15,0,lB>} 
box{<-31,0,0>,<0,50,1000> texture{pigment{colLum}  finish{ambient 0 diffuse 0.3}} translate <15,0,lB+62>} 
box{<0,0,0>,<50,50,2000> texture{txtBL_1} no_shadow translate x*xPosBR_1}

plane{z,-10 texture{pigment{colLum*0.2} finish{ambient 0 diffuse 0}} no_shadow hollow}
plane{x,0 rotate y*-20 translate -10*x texture{pigment{colLum*0.2} finish{ambient 0 diffuse 0}} no_shadow hollow}
plane{y,0 texture{pigment{Black} finish{ambient 0 diffuse 0 reflection 0.5}}}